自己写了一个：自动配置/切换/查看JDK环境变量的批处理脚本。顺带3个JDK版本分别是：jdk1.6.0_43，jdk1.7.0_80，jdk1.8.0_131，大家就不用自己辛辛苦苦的去安装JDK了，直接拿来就能用。分享给大家

@echo off

set home=%JAVA_HOME%
if defined home (
	echo 删除现有的JAVA_HOME环境变量
	wmic ENVIRONMENT where "name='JAVA_HOME'" delete
)

set class=%classpath%
if defined class (
	echo 删除现有的classpath环境变量
	wmic ENVIRONMENT where "name='classpath'" delete
)
start %~dp0\RefreshEnv.exe

echo 请输入JDK所在路径：
set /p JDK_HOME=
wmic ENVIRONMENT create name="JAVA_HOME",username="<system>",VariableValue="%JDK_HOME%"
wmic ENVIRONMENT create name="classpath",username="<system>",VariableValue=".;%%JAVA_HOME%%\lib;%%JAVA_HOME%%\lib\tools.jar"

rem
echo %Path% | findstr "JAVA_HOME" >nul
if %errorlevel% equ 1 (
	wmic ENVIRONMENT where "name='path' and username='<SYSTEM>'" set VariableValue="%path%;%%JAVA_HOME%%\bin;"
)
rem
start %~dp0\RefreshEnv.exe

echo 请按任意键退出!
pause>nul

@echo on

这段批处理代码：

1，首先查看系统环境变量中是否存在JDK相关的环境变量，如有则删除掉。

2，用户输入本地安装JDK路径，添加JAVA_HOME，classpath等环境变量。

3，判断系统Path变量中是否包含jdk相关的配置，没有就添加。

双击"JDK环境变量自动配置.bat"文件运行批处理脚本，根据提示操作即可,如下图所示：

1.1、系统中存在JDK相关的配置时：

2，系统中不存在JDK相关的配置时(首次配置时)：

二，JDK版本切换.bat

@echo off

rem --- Base Config 配置JDK的安装目录(需要修改成自己的路径哟) ---
:init
set JAVA_HOME_1_8=D:\IT_Softwares\JDK\JDK8\jdk1.8.0_181
set JAVA_HOME_1_7=D:\IT_Softwares\JDK\JDK7\jdk1.7.0_80
set JAVA_HOME_1_6=D:\IT_Softwares\JDK\JDK6\jdk1.6.0_43
:start
echo 当前使用的JDK 版本:
java -version
echo.
echo =============================================
echo 选择JDK版本
echo 1.6 请输入 1
echo 1.7 请输入 2
echo 1.8 请输入 3
echo =============================================
:select
set /p opt=请选择JDK版本：
if %opt%==1 (
    set TARGET_JAVA_HOME=%JAVA_HOME_1_6%
)
if %opt%==2 (
    set TARGET_JAVA_HOME=%JAVA_HOME_1_7%
)
if %opt%==3 (
    set TARGET_JAVA_HOME=%JAVA_HOME_1_8%
)

echo 当前选择的Java路径:%TARGET_JAVA_HOME%

wmic ENVIRONMENT where "name='JAVA_HOME'" delete
wmic ENVIRONMENT create name="JAVA_HOME",username="<system>",VariableValue=%TARGET_JAVA_HOME%

rem
start %~dp0\RefreshEnv.exe

echo 请按任意键退出!
pause>nul

@echo on

注意：5-7行代码修改成自己本地的JDK路径

这段批处理脚本代码是根据我们自己设置的JDK路径，然后选择的JDK版本来动态修改JAVA_HOME环境变量的，然后RefreshEnv.exe来刷新环境变量的值。

双击JDK版本切换.bat文件运行批处理脚本，根据提示操作即可，如下图所示：

三，JDK版本查看.bat

@echo off
echo 当前使用的JDK 版本:
java -version
set /p v=按任意键退出!
@echo on

四，下载地址